Вопросы по С/С++ (СИ)

[Viper_Snake]

veso74 писал(а):

Идея:

В:

Код:

C:\Program Files (x86)\Arduino\hardware\arduino\avr\cores\arduino\wiring_shift.c

строка 25..38, посмотрите как написано shiftIn() для 8 бит. Напишите напр. локальную функцию (под другим именем) для 4 * 8 бита (long) или больше (5 байт) (при этом, конечно, соблюдая разрядность новых типов данных - некоторые типы перейдут на uint64_t. А можете оптимизировать: до uint32_t, как написали напр. есть ненужный байт).

Код:

uint8_t shiftIn(uint8_t dataPin, uint8_t clockPin, uint8_t bitOrder) {
   uint8_t value = 0;
   uint8_t i;

   for (i = 0; i < 8; ++i) {
      digitalWrite(clockPin, HIGH);
      if (bitOrder == LSBFIRST)
         value |= digitalRead(dataPin) << i;
      else
         value |= digitalRead(dataPin) << (7 - i);
      digitalWrite(clockPin, LOW);
   }
   return value;
}

Ну это как вариант, но потом придется 8-ми байтную простыню разбирать - узкоглазые с этим 5-ти байтным регистром как всегда подосрали ..

[veso74]

Viper_Snake, можете написать фразу другими словами? С русского толком не переводится до БГ , и не могу понять смисл.
Чувствую, что что-то не нравится, но что это ...

[Viper_Snake]

veso74 писал(а):

Viper_Snake, можете написать фразу другими словами? С русского толком не переводится до БГ , и не могу понять смисл.
Чувствую, что что-то не нравится, но что это ...

Я извиняюсь. Вариант хороший, но после его применения придется работать с большой переменной размером 8 байт. Китайцы с 5 битным регистром клавиатуры сделали очень нехорошо - в 4 бита не вместится, 8 бит - 3 бита лишние.

[VladislavS]

Если не выходить за пределы ардуины, то я бы вот так написал.

Спойлер

Код:

uint32_t readTMData()
{ 
  digitalWrite(PIN_STB, LOW);
  shiftOut(PIN_DIO, PIN_CLK, LSBFIRST, 0x42);
  pinMode(PIN_DIO, INPUT_PULLUP);
  delayMicroseconds(1);
  uint8_t tmp1 = shiftIn(PIN_DIO, PIN_CLK, LSBFIRST);
  uint8_t tmp2 = shiftIn(PIN_DIO, PIN_CLK, LSBFIRST);
  shiftIn(PIN_DIO, PIN_CLK, LSBFIRST);
  uint8_t tmp3 = shiftIn(PIN_DIO, PIN_CLK, LSBFIRST);
  uint8_t tmp4 = shiftIn(PIN_DIO, PIN_CLK, LSBFIRST);
  pinMode(PIN_DIO, OUTPUT);
  digitalWrite(PIN_STB, HIGH);
  return (uint32_t(0x80+tmp1)<<24)+(uint32_t(tmp2)<<16)+(uint32_t(tmp3)<<8)+tmp4;
}

Включить максимальную оптимизацию и молиться.

Чувствую, потребуются пояснения. Если это 8-битка, то операции сдвига локальных переменных на 24, 16 и 8 бит будут бесплатными. Результат возвращается через четыре РОН. Из shiftIn данные будут сразу в эти регистры записываться без каких-либо сдвигов.

Последний раз редактировалось VladislavS Вт авг 02, 2022 21:43:06, всего редактировалось 2 раз(а).

[veso74]

Спойлер

uint32_t readTMData() {
uint32_t data = 0;

for (uint8_t i = 0; i < 32; ++i) {
digitalWrite(PIN_CLK, HIGH);
data |= digitalRead(PIN_DIO) << i;
digitalWrite(PIN_CLK, LOW);
}

bitSet(data, 31); // ставим 31-й бит в 1

pinMode(PIN_DIO, OUTPUT);
digitalWrite(PIN_STB, HIGH);

return data;
}

...
uint32_t a = readTMData();

Последний раз редактировалось veso74 Вт авг 02, 2022 21:48:38, всего редактировалось 2 раз(а).

[VladislavS]

veso74, там 5 байт, из которых часть не нужна.

[veso74]

Спойлер

Код:

uint32_t readTMData() {
  uint64_t data = 0;

  for (uint8_t i = 0; i < 16; ++i) {
    digitalWrite(PIN_CLK, HIGH);
    data |= digitalRead(PIN_DIO) << i;
    digitalWrite(PIN_CLK, LOW);
  }

  for (uint8_t i = 24; i < 40; ++i) {
    digitalWrite(PIN_CLK, HIGH);
    data |= digitalRead(PIN_DIO) << i;
    digitalWrite(PIN_CLK, LOW);
  }

  bitSet(data, 31);  // ставим 31-й бит в 1

  pinMode(PIN_DIO, OUTPUT);
  digitalWrite(PIN_STB, HIGH);

  return data;
}

...
uint32_t a = readTMData();

[VladislavS]

veso74, не то. Считать надо 40 бит. Из них взять 32.

[veso74]

сложно, сейчас перенесу на бумагу, другого выхода нет

[VladislavS]

veso74, не стоит. Понятно что вы хотите сделать. На 8-битке это будет работать хуже.

[veso74]

Спойлер

Код:

uint32_t readTMData() {
  uint32_t data = 0;

  for (uint8_t i = 0; i < 16; ++i) {
    digitalWrite(PIN_CLK, HIGH);
    data |= digitalRead(PIN_DIO) << i;
    digitalWrite(PIN_CLK, LOW);
  }

  digitalRead(PIN_DIO);  // ???

  for (uint8_t i = 24; i < 32; ++i) {
    digitalWrite(PIN_CLK, HIGH);
    data |= digitalRead(PIN_DIO) << i;
    digitalWrite(PIN_CLK, LOW);
  }

  bitSet(data, 31);  // ставим 31-й бит в 1

  pinMode(PIN_DIO, OUTPUT);
  digitalWrite(PIN_STB, HIGH);

  return data;
}

Ок, не уверен, как он перейдет с 16 на 24 бита. Ладно, мне нечего пробовать. Я дал это только как идею, в реальном использовании, если необходимо, измените его в соответствии с потребностями.

Последний раз редактировалось veso74 Вт авг 02, 2022 22:09:02, всего редактировалось 2 раз(а).

[VladislavS]

Ну почти, только между двумя 16-битными чтениями не digitalRead, а shiftIn (или просто 8 клоков) нужен. Но, повторюсь, это будет хуже пяти 8-битных shiftIn из-за длинных сдвигов.

[veso74]

Короче как бы взяли 40 бит, вычеркнули 8 и упаковали до 32 (изменив 31-й байт)?
Время определяющее? (светодиодная индикация напр. или что-то еще?)

я бы поставил expander, он бы сигнализировал по interrupt при действие и никак не занимать бы центральный mcu в другое время (с сканирования неактивных кнопок). Но это без знания Вашего устройства.

[MOHCTEP]

Еще вариант псевдокода, собственно идеи ради, так как как в железке проверить не могу.

Код:

union result{
   uint8_t bytes[4];
   ulong data;
}

void readTMData(){
   uint8_t count = 0;
   for(uint8_t i = 0; i < 5; i++){// bytes from TM1628
      if(i == 2) continue;
      result.bytes[count++] = shiftIn(PIN_DIO, PIN_CLK, LSBFIRST);
   }
   result.bytes[3] |= 0x80; // ставим 7-й бит в 1.
   // используем result.data для анализа кнопок
}

[VladislavS]

MOHCTEP, 3-й байт таки тоже надо вычитывать, но не использовать. При оптимизации по скорости есть большая вероятность, что компилятор раскрутит ваш цикл до моей версии.

И union тут не нужен совсем. Компиляторы прекрасно умеют писать байты в 32-битные переменные просто в один из четырёх восьмибитных регистров.

[MOHCTEP]

VladislavS, Верно - не учел. Придется условие раскрыть. Как-то так, наверное, если без объединения.

Код:

ulong data;
void readTMData(){
   for(uint8_t i = 0; i < 5; i++){// bytes from TM1628
      if(i == 2){
        shiftIn(PIN_DIO, PIN_CLK, LSBFIRST); // в космос
        continue;
     }
     data <<= 8;
     data |= shiftIn(PIN_DIO, PIN_CLK, LSBFIRST);
   }
   data |= 0x80000000; // ставим 31-й бит в 1.
}

[ARV]

что-то я не понимаю: 2 лишних байта ОЗУ так критичны? 40 бит это 5 байт, считывайте все 5, а потом спокойно работайте побайтово с тремя нужными, обращаясь к нужным битам при помощи маски. или я упускаю что-то важное?

[Viper_Snake]

MOHCTEP писал(а):

VladislavS, Верно - не учел. Придется условие раскрыть. Как-то так, наверное, если без объединения.

Код:

ulong data;
void readTMData(){
   for(uint8_t i = 0; i < 5; i++){// bytes from TM1628
      if(i == 2){
        shiftIn(PIN_DIO, PIN_CLK, LSBFIRST); // в космос
        continue;
     }
     data <<= 8;
     data |= shiftIn(PIN_DIO, PIN_CLK, LSBFIRST);
   }
   data |= 0x80000000; // ставим 31-й бит в 1.
}

Изящно, но с точки зрения оптимизации те же яйца что у меня только в профиль. )

Добавлено after 19 minutes 7 seconds:

ARV писал(а):

что-то я не понимаю: 2 лишних байта ОЗУ так критичны? 40 бит это 5 байт, считывайте все 5, а потом спокойно работайте побайтово с тремя нужными, обращаясь к нужным битам при помощи маски. или я упускаю что-то важное?

Да в общем то ОЗУ хоть жопой ешь - контроллер tiny84 - 512 байт целых. Вопрос в другом - я ведь не зря сказал, что в ардуиновской среде ковыряюсь - мне удобнее взять стандартный тип переменной, чем свою 5-ти байтную сочинять. Весь этот онанизм вприсядку связан с тем, что появилась необходимость доработать уже сделанное ранее устройство и тут внезапно выяснилось, что надо где то добыть 3 дополнительных порта контроллера, один еще и в роли ацп. А порты внезапно все уже заняты и чтобы их освободить, три входа под датчики типа сухой контакт пришлось отдолжить у TM1628. В ДШ для этого очень удачно под индикацию не задействованы ноги SEG8 - SEG10. Кстати, не верьте ДШ TM1628 - ее бессовестно скопировали с AIP1628. Разница по ДШ как раз в пятом байте регистра кнопок - в ДШ на TM1628 их почему то гарисовано только 4. И схема подключения кнопок в 2-х местах разная.

[MOHCTEP]

Viper_Snake, Скорей всего ваша правда. Код на голеностопе состряпан, проверить не на чем. Думал, может циклом по-оптимальней будет.

Да в общем то ОЗУ хоть жопой ешь - контроллер tiny84 - 512 байт целых.

Мне этак примерно с tiny13 довелось помучиться, в озу "вписался", но прошивка занимала 1025 байт.

[VladislavS]

На 8-битке ещё вот так будет достаточно эффективно. Можно как 4, так и все 5 байт вытащить одинаково.

Спойлер

Код:

void readTMData(uint8_t *pdata)
{
  digitalWrite(PIN_STB, LOW);
  shiftOut(PIN_DIO, PIN_CLK, LSBFIRST, 0x42);
  pinMode(PIN_DIO, INPUT_PULLUP);
  delayMicroseconds(1);
  *pdata++ = shiftIn(PIN_DIO, PIN_CLK, LSBFIRST) | 0x80;
  *pdata++ = shiftIn(PIN_DIO, PIN_CLK, LSBFIRST);
  shiftIn(PIN_DIO, PIN_CLK, LSBFIRST);
  *pdata++ = shiftIn(PIN_DIO, PIN_CLK, LSBFIRST);
  *pdata = shiftIn(PIN_DIO, PIN_CLK, LSBFIRST);
  pinMode(PIN_DIO, OUTPUT);
  digitalWrite(PIN_STB, HIGH);
}

Ну а дальше - вылазить из ардуины.